-->

Sunday 22 April 2012

Activate windows 7 for free

copy blow text and save as actvation.cmd file in notepad and close notepad and open folder where you save the activation.cmd file and run as administor
code is here








@echo off & color 1F
setlocal ENABLEDELAYEDEXPANSION
for /F "usebackq tokens=4 delims= " %%I in (`%SYSTEMROOT%\system32\chcp.com`) do set ACTCODEPAGE=%%I
"%SYSTEMROOT%\system32\chcp.com" 437 >nul


rem     *** Internet KMS Activation Script (OCT 23, 2010) ***


rem     [Step 1]
rem     This step is optional and you may skip it.

cls
echo Microsoft (R) Windows Software Licensing.
echo Copyright (C) Microsoft Corporation. All rights reserved.
echo.
echo Step 1: Select your Windows(R) 7 edition.
echo.
echo.
echo This tool can help you activate
echo one of the following Microsoft(R) products:
echo.
echo A) Windows(R) 7 Professional
echo B) Windows(R) 7 Professional N
echo C) Windows(R) 7 Enterprise
echo D) Windows(R) 7 Enterprise E
echo E) Windows(R) 7 Enterprise N
echo.
echo F) {Skip this step}
echo.
echo.

choice /C ABCDEF /N /M "Select one of the options above (A-F):"
if ERRORLEVEL 6 goto :step2
if ERRORLEVEL 5 set PRODUCTKEY=YDRBP-3D83W-TY26F-D46B2-XCKRJ
if ERRORLEVEL 4 set PRODUCTKEY=C29WB-22CC8-VJ326-GHFJW-H9DH4
if ERRORLEVEL 3 set PRODUCTKEY=33PXH-7Y6KF-2VJC9-XBBR8-HVTHH
if ERRORLEVEL 2 set PRODUCTKEY=MRPKT-YTG23-K7D7T-X2JMM-QY7MG
if ERRORLEVEL 1 set PRODUCTKEY=FJ82H-XT6CR-J8D7P-XQJJ2-GPDD4

echo.
echo.
"%SYSTEMROOT%\system32\cscript.exe" "%SYSTEMROOT%\system32\slmgr.vbs" -ipk %PRODUCTKEY%
pause


:step2
rem     [Step 2]
rem     All servers are tested/alive.
rem     If you have problems and want to re-check any of them
rem     don't just ping it, use telnet tool instead:
rem     telnet <KMS host IP-address or DNS name> <port>
rem     or a port scanner like Microsoft(R) PortQry:
rem     http://www.microsoft.com/downloads/details.aspx?familyid=89811747-C74B-4638-A2D5-AC828BDC6983

cls
echo Microsoft (R) Windows Software Licensing.
echo Copyright (C) Microsoft Corporation. All rights reserved.
echo.
echo Step 2: Select Key Management Service (KMS) host.
echo.
echo. 
echo Select a server from the list below to set it as the KMS host
echo for your Windows Server(R) operating system:
echo.
echo A) yuna.no-ip.info
echo B) vault-tec.no-ip.org
echo C) 91.149.135.121
echo D) 194.0.116.18
echo E) netplus.no-ip.info
echo.
echo F) {Skip this step}
echo.
echo.

choice /C ABCDEF /N /M "Select one of the options above (A-F):"
if ERRORLEVEL 6 goto :step3
if ERRORLEVEL 5 set KMSS=netplus.no-ip.info:1688
if ERRORLEVEL 4 set KMSS=194.0.116.18:1688
if ERRORLEVEL 3 set KMSS=91.149.135.121:1688
if ERRORLEVEL 2 set KMSS=vault-tec.no-ip.org:1688
if ERRORLEVEL 1 set KMSS=yuna.no-ip.info:1688

echo.
echo.
"%SYSTEMROOT%\system32\cscript.exe" "%SYSTEMROOT%\system32\slmgr.vbs" -skms %KMSS%
endlocal
pause


:step3
rem     [Step 3]

cls
echo Microsoft (R) Windows Software Licensing.
echo Copyright (C) Microsoft Corporation. All rights reserved.
echo.
echo Step 3: Activation.
echo.
echo.

echo Resynching time...
"%SYSTEMROOT%\system32\sc.exe" start w32time >nul
"%SYSTEMROOT%\system32\timeout.exe" /T 2 /NOBREAK >nul
for /F "usebackq delims=" %%I in (`%SYSTEMROOT%\system32\sc.exe query w32time ^| findstr /R "STATE"`) do set W32TIMESTATE=%%I
for /F "usebackq tokens=4 delims= " %%I in ('%W32TIMESTATE%') do set W32TIMESTATE=%%I
if /I "%W32TIMESTATE%" NEQ "RUNNING" echo WARNING: Could not start Windows Time service!
"%SYSTEMROOT%\system32\w32tm.exe" /resync
echo.
"%SYSTEMROOT%\system32\cscript.exe" "%SYSTEMROOT%\system32\slmgr.vbs" -ato
pause


rem     [Step 4]

cls
echo Microsoft (R) Windows Software Licensing.
echo Copyright (C) Microsoft Corporation. All rights reserved.
echo.
echo Step 4: Activation Status Check.
echo.
echo.

"%SYSTEMROOT%\system32\cscript.exe" "%SYSTEMROOT%\system32\slmgr.vbs" -dli
"%SYSTEMROOT%\system32\chcp.com" %ACTCODEPAGE% >nul
echo Press any key to exit . . . & pause >nul





No comments:

Post a Comment